src/test/rustdoc-gui/search-result-display.goml

   1 // Checks that the search results have the expected width.
   2 goto: "file://" + |DOC_PATH| + "/test_docs/index.html"
   3 size: (900, 1000)
   4 write: (".search-input", "test")
   5 // To be SURE that the search will be run.
   6 press-key: 'Enter'
   7 wait-for: "#crate-search"
   8 // The width is returned by "getComputedStyle" which returns the exact number instead of the
   9 // CSS rule which is "50%"...
  10 assert-css: (".search-results div.desc", {"width": "310px"})
  11 size: (600, 100)
  12 // As counter-intuitive as it may seem, in this width, the width is "100%", which is why
  13 // when computed it's larger.
  14 assert-css: (".search-results div.desc", {"width": "566px"})
  15
  16 // The result set is all on one line.
  17 assert-css: (".search-results .result-name > span", {"display": "inline"})
  18
  19 // Check that the crate filter `<select>` is correctly handled when it goes to next line.
  20 // To do so we need to update the length of one of its `<option>`.
  21 size: (900, 900)
  22
  23 // First we check the current width, height and position.
  24 assert-css: ("#crate-search", {"width": "223px"})
  25 assert-css: (".search-results-title", {"height": "44px", "width": "336px"})
  26
  27 // Then we update the text of one of the `<option>`.
  28 text: (
  29     "#crate-search option",
  30     "sdjfaksdjfaksjdbfkadsbfkjsadbfkdsbkfbsadkjfbkdsabfkadsfkjdsafa",
  31 )
  32
  33 // Then we compare again to confirm the height didn't change.
  34 assert-css: ("#crate-search", {"width": "527px"})
  35 assert-css: (".search-results-title", {"height": "44px", "width": "640px"})
  36 // And we check that the `<select>` isn't bigger than its container (".search-results-title").
  37 assert-css: ("#search", {"width": "640px"})
  38
  39 // Now checking that the crate filter is working as expected too.
  40 show-text: true
  41 define-function: (
  42     "check-filter",
  43     (theme, border, filter, hover_border, hover_filter),
  44     [
  45         ("local-storage", {"rustdoc-theme": |theme|, "rustdoc-use-system-theme": "false"}),
  46         ("reload"),
  47         ("wait-for", "#crate-search"),
  48         ("assert-css", ("#crate-search", {"border": "1px solid " + |border|})),
  49         ("assert-css", ("#crate-search-div::after", {"filter": |filter|})),
  50         ("move-cursor-to", "#crate-search"),
  51         ("assert-css", ("#crate-search", {"border": "1px solid " + |hover_border|})),
  52         ("assert-css", ("#crate-search-div::after", {"filter": |hover_filter|})),
  53         ("move-cursor-to", ".search-input"),
  54     ],
  55 )
  56
  57 call-function: ("check-filter", {
  58     "theme": "ayu",
  59     "border": "rgb(92, 103, 115)",
  60     "filter": "invert(0.41) sepia(0.12) saturate(4.87) hue-rotate(171deg) brightness(0.94) contrast(0.94)",
  61     "hover_border": "rgb(224, 224, 224)",
  62     "hover_filter": "invert(0.98) sepia(0.12) saturate(0.81) hue-rotate(343deg) brightness(1.13) contrast(0.76)",
  63 })
  64 call-function: ("check-filter", {
  65     "theme": "dark",
  66     "border": "rgb(224, 224, 224)",
  67     "filter": "invert(0.94) sepia(0) saturate(7.21) hue-rotate(255deg) brightness(0.9) contrast(0.9)",
  68     "hover_border": "rgb(33, 150, 243)",
  69     "hover_filter": "invert(0.69) sepia(0.6) saturate(66.13) hue-rotate(184deg) brightness(1) contrast(0.91)",
  70 })
  71 call-function: ("check-filter", {
  72     "theme": "light",
  73     "border": "rgb(224, 224, 224)",
  74     "filter": "invert(1) sepia(0) saturate(42.23) hue-rotate(289deg) brightness(1.14) contrast(0.76)",
  75     "hover_border": "rgb(113, 113, 113)",
  76     "hover_filter": "invert(0.44) sepia(0.18) saturate(0.23) hue-rotate(317deg) brightness(0.96) contrast(0.93)",
  77 })