src/rt/arch/x86_64/morestack.S

   1 /*
   2         __morestack
   3
   4         See i386/morestack.S for the lengthy, general explanation.
   5 */
   6
   7 .text
   8
   9 #if defined(__APPLE__) || defined(_WIN32)
  10 #define UPCALL_NEW_STACK        _upcall_new_stack
  11 #define UPCALL_DEL_STACK        _upcall_del_stack
  12 #define MORESTACK               ___morestack
  13 #else
  14 #define UPCALL_NEW_STACK        upcall_new_stack
  15 #define UPCALL_DEL_STACK        upcall_del_stack
  16 #define MORESTACK               __morestack
  17 #endif
  18
  19 .globl UPCALL_NEW_STACK
  20 .globl UPCALL_DEL_STACK
  21 .globl MORESTACK
  22
  23 #if defined(__linux__)
  24         .hidden MORESTACK
  25 #else
  26 #if defined(__APPLE__)
  27         .private_extern MORESTACK
  28 #endif
  29 #endif
  30
  31 #ifdef __ELF__
  32         .type MORESTACK,@function
  33 #endif
  34
  35
  36 #if defined(__linux__) || defined(__APPLE__)
  37 MORESTACK:
  38         .cfi_startproc
  39
  40         pushq %rbp
  41         // The CFA is 24 bytes above the register that it will
  42         // be associated with for this frame (%rbp). That is 8
  43         // bytes greater than a normal frame, to allow the unwinder
  44         // to skip the partial frame of the original function.
  45         .cfi_def_cfa_offset 24
  46         // %rbp is -24 bytes from the CFA
  47         .cfi_offset %rbp, -24
  48         movq %rsp, %rbp
  49         // Calculate the CFA as on offset from %ebp
  50         .cfi_def_cfa_register %rbp
  51
  52         pushq $0 // Alignment
  53
  54         // FIXME: libgcc also saves rax. not sure if we need to
  55
  56         // Save argument registers of the original function
  57         pushq   %rdi
  58         pushq   %rsi
  59         pushq   %rdx
  60         pushq   %rcx
  61         pushq   %r8
  62         pushq   %r9
  63
  64         // Calculate the address of the stack arguments.
  65         // We have the base pointer, __morestack's return address,
  66         // and __morestack's caller's return address to skip
  67         movq %rbp, %rax
  68         addq $24, %rax  // Base pointer, return address x2
  69
  70         // The arguments to __morestack are passed in %r10 & %r11
  71
  72         movq %r11, %rdx // Size of stack arguments
  73         movq %rax, %rsi // Address of stack arguments
  74         movq %r10, %rdi // The amount of stack needed
  75
  76 #ifdef __APPLE__
  77         call UPCALL_NEW_STACK
  78 #endif
  79 #ifdef __linux__
  80         call UPCALL_NEW_STACK@PLT
  81 #endif
  82
  83         // Pop the saved arguments
  84         popq %r9
  85         popq %r8
  86         popq %rcx
  87         popq %rdx
  88         popq %rsi
  89         popq %rdi
  90
  91         // Pop the unwinding %rsp
  92         addq $8, %rsp
  93
  94         movq 8(%rbp),%r10       // Grab the return pointer.
  95         incq %r10               // Skip past the `ret` in our parent frame
  96         movq %rax,%rsp          // Switch to the new stack.
  97
  98         call *%r10              // Reenter the caller function
  99
 100         // Switch back to the rust stack
 101         movq %rbp, %rsp
 102
 103         // Save the return value
 104         pushq %rax
 105
 106 #ifdef __APPLE__
 107         call UPCALL_DEL_STACK
 108 #endif
 109 #ifdef __linux__
 110         call UPCALL_DEL_STACK@PLT
 111 #endif
 112
 113         popq %rax // Restore the return value
 114         popq %rbp
 115         // FIXME: I don't think these rules are necessary
 116         // since the unwinder should never encounter an instruction
 117         // pointer pointing here.
 118         .cfi_restore %rbp
 119         .cfi_def_cfa %rsp, 16
 120         ret
 121
 122         .cfi_endproc
 123
 124 #else
 125 MORESTACK:
 126         ret
 127 #endif