src/libstd/sys/sgx/abi/entry.S

   1 /*  This symbol is used at runtime to figure out the virtual address that the */
   2 /*  enclave is loaded at. */
   3 .section absolute
   4 .global IMAGE_BASE
   5 IMAGE_BASE:
   6
   7 .section ".note.x86_64-fortanix-unknown-sgx", "", @note
   8     .align 4
   9     .long 1f - 0f              /* name length (not including padding) */
  10     .long 3f - 2f              /* desc length (not including padding) */
  11     .long 1                    /* type = NT_VERSION */
  12 0:  .asciz "toolchain-version" /* name */
  13 1:  .align 4
  14 2:  .long 0                    /* desc - toolchain version number, 32-bit LE */
  15 3:  .align 4
  16
  17 .section .rodata
  18 /*  The XSAVE area needs to be a large chunk of readable memory, but since we are */
  19 /*  going to restore everything to its initial state (XSTATE_BV=0), only certain */
  20 /*  parts need to have a defined value. In particular: */
  21 /*  */
  22 /*    * MXCSR in the legacy area. This register is always restored if RFBM[1] or */
  23 /*      RFBM[2] is set, regardless of the value of XSTATE_BV */
  24 /*    * XSAVE header */
  25 .align 64
  26 .Lxsave_clear:
  27 .org .+24
  28 .Lxsave_mxcsr:
  29     .int 0
  30
  31 /*  We can store a bunch of data in the gap between MXCSR and the XSAVE header */
  32
  33 /*  The following symbols point at read-only data that will be filled in by the */
  34 /*  post-linker. */
  35
  36 /*  When using this macro, don't forget to adjust the linker version script! */
  37 .macro globvar name:req size:req
  38     .global \name
  39     .protected \name
  40     .align \size
  41     .size \name , \size
  42     \name :
  43         .org .+\size
  44 .endm
  45     /*  The base address (relative to enclave start) of the heap area */
  46     globvar HEAP_BASE 8
  47     /*  The heap size in bytes */
  48     globvar HEAP_SIZE 8
  49     /*  Value of the RELA entry in the dynamic table */
  50     globvar RELA 8
  51     /*  Value of the RELACOUNT entry in the dynamic table */
  52     globvar RELACOUNT 8
  53     /*  The enclave size in bytes */
  54     globvar ENCLAVE_SIZE 8
  55     /*  The base address (relative to enclave start) of the enclave configuration area */
  56     globvar CFGDATA_BASE 8
  57     /*  Non-zero if debugging is enabled, zero otherwise */
  58     globvar DEBUG 1
  59     /*  The base address (relative to enclave start) of the enclave text section */
  60     globvar TEXT_BASE 8
  61     /*  The size in bytes of enclacve text section */
  62     globvar TEXT_SIZE 8
  63     /*  The base address (relative to enclave start) of the enclave EH_FRM_HDR section */
  64     globvar EH_FRM_HDR_BASE 8
  65     /*  The size in bytes of enclacve EH_FRM_HDR section */
  66     globvar EH_FRM_HDR_SIZE 8
  67
  68 .org .Lxsave_clear+512
  69 .Lxsave_header:
  70     .int 0, 0 /*  XSTATE_BV */
  71     .int 0, 0 /*  XCOMP_BV */
  72     .org .+48 /*  reserved bits */
  73
  74 .data
  75 .Laborted:
  76     .byte 0
  77
  78 /*  TCS local storage section */
  79 .equ tcsls_tos,                 0x00 /*  initialized by loader to *offset* from image base to TOS */
  80 .equ tcsls_flags,               0x08 /*  initialized by loader */
  81 .equ tcsls_flag_secondary,      0    /*  initialized by loader; 0 = standard TCS, 1 = secondary TCS */
  82 .equ tcsls_flag_init_once,      1    /*  initialized by loader to 0 */
  83 /*  14 unused bits */
  84 .equ tcsls_user_fcw,            0x0a
  85 .equ tcsls_user_mxcsr,          0x0c
  86 .equ tcsls_last_rsp,            0x10 /*  initialized by loader to 0 */
  87 .equ tcsls_panic_last_rsp,      0x18 /*  initialized by loader to 0 */
  88 .equ tcsls_debug_panic_buf_ptr, 0x20 /*  initialized by loader to 0 */
  89 .equ tcsls_user_rsp,            0x28
  90 .equ tcsls_user_retip,          0x30
  91 .equ tcsls_user_rbp,            0x38
  92 .equ tcsls_user_r12,            0x40
  93 .equ tcsls_user_r13,            0x48
  94 .equ tcsls_user_r14,            0x50
  95 .equ tcsls_user_r15,            0x58
  96 .equ tcsls_tls_ptr,             0x60
  97 .equ tcsls_tcs_addr,            0x68
  98
  99 .macro load_tcsls_flag_secondary_bool reg:req comments:vararg
 100     .ifne tcsls_flag_secondary /* to convert to a bool, must be the first bit */
 101     .abort
 102     .endif
 103         mov $(1<<tcsls_flag_secondary),%e\reg
 104         and %gs:tcsls_flags,%\reg
 105 .endm
 106
 107 /* We place the ELF entry point in a separate section so it can be removed by
 108    elf2sgxs */
 109 .section .text_no_sgx, "ax"
 110 .Lelf_entry_error_msg:
 111     .ascii "Error: This file is an SGX enclave which cannot be executed as a standard Linux binary.\nSee the installation guide at https://edp.fortanix.com/docs/installation/guide/ on how to use 'cargo run' or follow the steps at https://edp.fortanix.com/docs/tasks/deployment/ for manual deployment.\n"
 112 .Lelf_entry_error_msg_end:
 113
 114 .global elf_entry
 115 .type elf_entry,function
 116 elf_entry:
 117 /* print error message */
 118     movq $2,%rdi                      /* write to stderr (fd 2) */
 119     lea .Lelf_entry_error_msg(%rip),%rsi
 120     movq $.Lelf_entry_error_msg_end-.Lelf_entry_error_msg,%rdx
 121 .Lelf_entry_call:
 122     movq $1,%rax                      /* write() syscall        */
 123     syscall
 124     test %rax,%rax
 125     jle .Lelf_exit                    /* exit on error          */
 126     add %rax,%rsi
 127     sub %rax,%rdx                     /* all chars written?     */
 128     jnz .Lelf_entry_call
 129
 130 .Lelf_exit:
 131     movq $60,%rax                     /* exit() syscall         */
 132     movq $1,%rdi                      /* exit code 1            */
 133     syscall
 134     ud2                               /* should not be reached  */
 135 /*  end elf_entry */
 136
 137 .text
 138 .global sgx_entry
 139 .type sgx_entry,function
 140 sgx_entry:
 141 /*  save user registers */
 142     mov %rcx,%gs:tcsls_user_retip
 143     mov %rsp,%gs:tcsls_user_rsp
 144     mov %rbp,%gs:tcsls_user_rbp
 145     mov %r12,%gs:tcsls_user_r12
 146     mov %r13,%gs:tcsls_user_r13
 147     mov %r14,%gs:tcsls_user_r14
 148     mov %r15,%gs:tcsls_user_r15
 149     mov %rbx,%gs:tcsls_tcs_addr
 150     stmxcsr %gs:tcsls_user_mxcsr
 151     fnstcw %gs:tcsls_user_fcw
 152
 153 /*  reset user state */
 154 /*    - DF flag: x86-64 ABI requires DF to be unset at function entry/exit */
 155 /*    - AC flag: AEX on misaligned memory accesses leaks side channel info */
 156     pushfq
 157     andq $~0x40400, (%rsp)
 158     popfq
 159
 160 /*  check for debug buffer pointer */
 161     testb  $0xff,DEBUG(%rip)
 162     jz .Lskip_debug_init
 163     mov %r10,%gs:tcsls_debug_panic_buf_ptr
 164 .Lskip_debug_init:
 165 /*  check for abort */
 166     bt $0,.Laborted(%rip)
 167     jc .Lreentry_panic
 168 /*  check if returning from usercall */
 169     mov %gs:tcsls_last_rsp,%r11
 170     test %r11,%r11
 171     jnz .Lusercall_ret
 172 /*  setup stack */
 173     mov %gs:tcsls_tos,%rsp /*  initially, RSP is not set to the correct value */
 174                            /*  here. This is fixed below under "adjust stack". */
 175 /*  check for thread init */
 176     bts $tcsls_flag_init_once,%gs:tcsls_flags
 177     jc .Lskip_init
 178 /*  adjust stack */
 179     lea IMAGE_BASE(%rip),%rax
 180     add %rax,%rsp
 181     mov %rsp,%gs:tcsls_tos
 182 /*  call tcs_init */
 183 /*  store caller-saved registers in callee-saved registers */
 184     mov %rdi,%rbx
 185     mov %rsi,%r12
 186     mov %rdx,%r13
 187     mov %r8,%r14
 188     mov %r9,%r15
 189     load_tcsls_flag_secondary_bool di /* RDI = tcs_init() argument: secondary: bool */
 190     call tcs_init
 191 /*  reload caller-saved registers */
 192     mov %rbx,%rdi
 193     mov %r12,%rsi
 194     mov %r13,%rdx
 195     mov %r14,%r8
 196     mov %r15,%r9
 197 .Lskip_init:
 198 /*  call into main entry point */
 199     load_tcsls_flag_secondary_bool cx /* RCX = entry() argument: secondary: bool */
 200     call entry /* RDI, RSI, RDX, R8, R9 passed in from userspace */
 201     mov %rax,%rsi  /* RSI = return value */
 202     /* NOP: mov %rdx,%rdx */ /*  RDX = return value */
 203     xor %rdi,%rdi  /* RDI = normal exit */
 204 .Lexit:
 205 /*  clear general purpose register state */
 206     /*  RAX overwritten by ENCLU */
 207     /*  RBX set later */
 208     /*  RCX overwritten by ENCLU */
 209     /*  RDX contains return value */
 210     /*  RSP set later */
 211     /*  RBP set later */
 212     /*  RDI contains exit mode */
 213     /*  RSI contains return value */
 214     xor %r8,%r8
 215     xor %r9,%r9
 216     xor %r10,%r10
 217     xor %r11,%r11
 218     /*  R12 ~ R15 set by sgx_exit */
 219 .Lsgx_exit:
 220 /*  clear extended register state */
 221     mov %rdx, %rcx /*  save RDX */
 222     mov $-1, %rax
 223     mov %rax, %rdx
 224     xrstor .Lxsave_clear(%rip)
 225     mov %rcx, %rdx /*  restore RDX */
 226 /*  clear flags */
 227     pushq $0
 228     popfq
 229 /*  restore user registers */
 230     mov %gs:tcsls_user_r12,%r12
 231     mov %gs:tcsls_user_r13,%r13
 232     mov %gs:tcsls_user_r14,%r14
 233     mov %gs:tcsls_user_r15,%r15
 234     mov %gs:tcsls_user_retip,%rbx
 235     mov %gs:tcsls_user_rsp,%rsp
 236     mov %gs:tcsls_user_rbp,%rbp
 237     fldcw %gs:tcsls_user_fcw
 238     ldmxcsr %gs:tcsls_user_mxcsr
 239 /*  exit enclave */
 240     mov $0x4,%eax /*  EEXIT */
 241     enclu
 242 /*  end sgx_entry */
 243
 244 .Lreentry_panic:
 245     orq $8,%rsp
 246     jmp abort_reentry
 247
 248 /*  This *MUST* be called with 6 parameters, otherwise register information */
 249 /*  might leak! */
 250 .global usercall
 251 usercall:
 252     test %rcx,%rcx            /* check `abort` function argument */
 253     jnz .Lusercall_abort      /* abort is set, jump to abort code (unlikely forward conditional) */
 254     jmp .Lusercall_save_state /* non-aborting usercall */
 255 .Lusercall_abort:
 256 /* set aborted bit */
 257     movb $1,.Laborted(%rip)
 258 /* save registers in DEBUG mode, so that debugger can reconstruct the stack */
 259     testb $0xff,DEBUG(%rip)
 260     jz .Lusercall_noreturn
 261 .Lusercall_save_state:
 262 /*  save callee-saved state */
 263     push %r15
 264     push %r14
 265     push %r13
 266     push %r12
 267     push %rbp
 268     push %rbx
 269     sub $8, %rsp
 270     fstcw 4(%rsp)
 271     stmxcsr (%rsp)
 272     movq %rsp,%gs:tcsls_last_rsp
 273 .Lusercall_noreturn:
 274 /*  clear general purpose register state */
 275     /*  RAX overwritten by ENCLU */
 276     /*  RBX set by sgx_exit */
 277     /*  RCX overwritten by ENCLU */
 278     /*  RDX contains parameter */
 279     /*  RSP set by sgx_exit */
 280     /*  RBP set by sgx_exit */
 281     /*  RDI contains parameter */
 282     /*  RSI contains parameter */
 283     /*  R8 contains parameter */
 284     /*  R9 contains parameter */
 285     xor %r10,%r10
 286     xor %r11,%r11
 287     /*  R12 ~ R15 set by sgx_exit */
 288 /*  extended registers/flags cleared by sgx_exit */
 289 /*  exit */
 290     jmp .Lsgx_exit
 291 .Lusercall_ret:
 292     movq $0,%gs:tcsls_last_rsp
 293 /*  restore callee-saved state, cf. "save" above */
 294     mov %r11,%rsp
 295     ldmxcsr (%rsp)
 296     fldcw 4(%rsp)
 297     add $8, %rsp
 298     pop %rbx
 299     pop %rbp
 300     pop %r12
 301     pop %r13
 302     pop %r14
 303     pop %r15
 304 /*  return */
 305     mov %rsi,%rax /*  RAX = return value */
 306     /* NOP: mov %rdx,%rdx */ /*  RDX = return value */
 307     ret
 308
 309 /*
 310 The following functions need to be defined externally:
 311 ```
 312 // Called by entry code on re-entry after exit
 313 extern "C" fn abort_reentry() -> !;
 314
 315 // Called once when a TCS is first entered
 316 extern "C" fn tcs_init(secondary: bool);
 317
 318 // Standard TCS entrypoint
 319 extern "C" fn entry(p1: u64, p2: u64, p3: u64, secondary: bool, p4: u64, p5: u64) -> (u64, u64);
 320 ```
 321 */
 322
 323 .global get_tcs_addr
 324 get_tcs_addr:
 325     mov %gs:tcsls_tcs_addr,%rax
 326     ret
 327
 328 .global get_tls_ptr
 329 get_tls_ptr:
 330     mov %gs:tcsls_tls_ptr,%rax
 331     ret
 332
 333 .global set_tls_ptr
 334 set_tls_ptr:
 335     mov %rdi,%gs:tcsls_tls_ptr
 336     ret
 337
 338 .global take_debug_panic_buf_ptr
 339 take_debug_panic_buf_ptr:
 340     xor %rax,%rax
 341     xchg %gs:tcsls_debug_panic_buf_ptr,%rax
 342     ret