src/libstd/sys/sgx/abi/entry.S

   1 /*  This symbol is used at runtime to figure out the virtual address that the */
   2 /*  enclave is loaded at. */
   3 .section absolute
   4 .global IMAGE_BASE
   5 IMAGE_BASE:
   6
   7 .section ".note.x86_64-fortanix-unknown-sgx", "", @note
   8     .align 4
   9     .long 1f - 0f              /* name length (not including padding) */
  10     .long 3f - 2f              /* desc length (not including padding) */
  11     .long 1                    /* type = NT_VERSION */
  12 0:  .asciz "toolchain-version" /* name */
  13 1:  .align 4
  14 2:  .long 0                    /* desc - toolchain version number, 32-bit LE */
  15 3:  .align 4
  16
  17 .section .rodata
  18 /*  The XSAVE area needs to be a large chunk of readable memory, but since we are */
  19 /*  going to restore everything to its initial state (XSTATE_BV=0), only certain */
  20 /*  parts need to have a defined value. In particular: */
  21 /*  */
  22 /*    * MXCSR in the legacy area. This register is always restored if RFBM[1] or */
  23 /*      RFBM[2] is set, regardless of the value of XSTATE_BV */
  24 /*    * XSAVE header */
  25 .align 64
  26 .Lxsave_clear:
  27 .org .+24
  28 .Lxsave_mxcsr:
  29     .int 0
  30
  31 /*  We can store a bunch of data in the gap between MXCSR and the XSAVE header */
  32
  33 /*  The following symbols point at read-only data that will be filled in by the */
  34 /*  post-linker. */
  35
  36 /*  When using this macro, don't forget to adjust the linker version script! */
  37 .macro globvar name:req size:req
  38     .global \name
  39     .protected \name
  40     .align \size
  41     .size \name , \size
  42     \name :
  43         .org .+\size
  44 .endm
  45     /*  The base address (relative to enclave start) of the heap area */
  46     globvar HEAP_BASE 8
  47     /*  The heap size in bytes */
  48     globvar HEAP_SIZE 8
  49     /*  Value of the RELA entry in the dynamic table */
  50     globvar RELA 8
  51     /*  Value of the RELACOUNT entry in the dynamic table */
  52     globvar RELACOUNT 8
  53     /*  The enclave size in bytes */
  54     globvar ENCLAVE_SIZE 8
  55     /*  The base address (relative to enclave start) of the enclave configuration area */
  56     globvar CFGDATA_BASE 8
  57     /*  Non-zero if debugging is enabled, zero otherwise */
  58     globvar DEBUG 1
  59     /*  The base address (relative to enclave start) of the enclave text section */
  60     globvar TEXT_BASE 8
  61     /*  The size in bytes of enclacve text section */
  62     globvar TEXT_SIZE 8
  63     /*  The base address (relative to enclave start) of the enclave EH_FRM_HDR section */
  64     globvar EH_FRM_HDR_BASE 8
  65     /*  The size in bytes of enclacve EH_FRM_HDR section */
  66     globvar EH_FRM_HDR_SIZE 8
  67
  68 .org .Lxsave_clear+512
  69 .Lxsave_header:
  70     .int 0, 0 /*  XSTATE_BV */
  71     .int 0, 0 /*  XCOMP_BV */
  72     .org .+48 /*  reserved bits */
  73
  74 .data
  75 .Laborted:
  76     .byte 0
  77
  78 /*  TCS local storage section */
  79 .equ tcsls_tos,                 0x00 /*  initialized by loader to *offset* from image base to TOS */
  80 .equ tcsls_flags,               0x08 /*  initialized by loader */
  81 .equ tcsls_flag_secondary,      0    /*  initialized by loader; 0 = standard TCS, 1 = secondary TCS */
  82 .equ tcsls_flag_init_once,      1    /*  initialized by loader to 0 */
  83 /*  14 unused bits */
  84 .equ tcsls_user_fcw,            0x0a
  85 .equ tcsls_user_mxcsr,          0x0c
  86 .equ tcsls_last_rsp,            0x10 /*  initialized by loader to 0 */
  87 .equ tcsls_panic_last_rsp,      0x18 /*  initialized by loader to 0 */
  88 .equ tcsls_debug_panic_buf_ptr, 0x20 /*  initialized by loader to 0 */
  89 .equ tcsls_user_rsp,            0x28
  90 .equ tcsls_user_retip,          0x30
  91 .equ tcsls_user_rbp,            0x38
  92 .equ tcsls_user_r12,            0x40
  93 .equ tcsls_user_r13,            0x48
  94 .equ tcsls_user_r14,            0x50
  95 .equ tcsls_user_r15,            0x58
  96 .equ tcsls_tls_ptr,             0x60
  97 .equ tcsls_tcs_addr,            0x68
  98
  99 .macro load_tcsls_flag_secondary_bool reg:req comments:vararg
 100     .ifne tcsls_flag_secondary /* to convert to a bool, must be the first bit */
 101     .abort
 102     .endif
 103         mov $(1<<tcsls_flag_secondary),%e\reg
 104         and %gs:tcsls_flags,%\reg
 105 .endm
 106
 107 .text
 108 .global sgx_entry
 109 .type sgx_entry,function
 110 sgx_entry:
 111 /*  save user registers */
 112     mov %rcx,%gs:tcsls_user_retip
 113     mov %rsp,%gs:tcsls_user_rsp
 114     mov %rbp,%gs:tcsls_user_rbp
 115     mov %r12,%gs:tcsls_user_r12
 116     mov %r13,%gs:tcsls_user_r13
 117     mov %r14,%gs:tcsls_user_r14
 118     mov %r15,%gs:tcsls_user_r15
 119     mov %rbx,%gs:tcsls_tcs_addr
 120     stmxcsr %gs:tcsls_user_mxcsr
 121     fnstcw %gs:tcsls_user_fcw
 122 /*  reset user state */
 123     cld /* x86-64 ABI requires DF to be unset at function entry/exit */
 124 /*  check for debug buffer pointer */
 125     testb  $0xff,DEBUG(%rip)
 126     jz .Lskip_debug_init
 127     mov %r10,%gs:tcsls_debug_panic_buf_ptr
 128 .Lskip_debug_init:
 129 /*  check for abort */
 130     bt $0,.Laborted(%rip)
 131     jc .Lreentry_panic
 132 /*  check if returning from usercall */
 133     mov %gs:tcsls_last_rsp,%r11
 134     test %r11,%r11
 135     jnz .Lusercall_ret
 136 /*  setup stack */
 137     mov %gs:tcsls_tos,%rsp /*  initially, RSP is not set to the correct value */
 138                            /*  here. This is fixed below under "adjust stack". */
 139 /*  check for thread init */
 140     bts $tcsls_flag_init_once,%gs:tcsls_flags
 141     jc .Lskip_init
 142 /*  adjust stack */
 143     lea IMAGE_BASE(%rip),%rax
 144     add %rax,%rsp
 145     mov %rsp,%gs:tcsls_tos
 146 /*  call tcs_init */
 147 /*  store caller-saved registers in callee-saved registers */
 148     mov %rdi,%rbx
 149     mov %rsi,%r12
 150     mov %rdx,%r13
 151     mov %r8,%r14
 152     mov %r9,%r15
 153     load_tcsls_flag_secondary_bool di /* RDI = tcs_init() argument: secondary: bool */
 154     call tcs_init
 155 /*  reload caller-saved registers */
 156     mov %rbx,%rdi
 157     mov %r12,%rsi
 158     mov %r13,%rdx
 159     mov %r14,%r8
 160     mov %r15,%r9
 161 .Lskip_init:
 162 /*  call into main entry point */
 163     load_tcsls_flag_secondary_bool cx /* RCX = entry() argument: secondary: bool */
 164     call entry /* RDI, RSI, RDX, R8, R9 passed in from userspace */
 165     mov %rax,%rsi  /* RSI = return value */
 166     /* NOP: mov %rdx,%rdx */ /*  RDX = return value */
 167     xor %rdi,%rdi  /* RDI = normal exit */
 168 .Lexit:
 169 /*  clear general purpose register state */
 170     /*  RAX overwritten by ENCLU */
 171     /*  RBX set later */
 172     /*  RCX overwritten by ENCLU */
 173     /*  RDX contains return value */
 174     /*  RSP set later */
 175     /*  RBP set later */
 176     /*  RDI contains exit mode */
 177     /*  RSI contains return value */
 178     xor %r8,%r8
 179     xor %r9,%r9
 180     xor %r10,%r10
 181     xor %r11,%r11
 182     /*  R12 ~ R15 set by sgx_exit */
 183 .Lsgx_exit:
 184 /*  clear extended register state */
 185     mov %rdx, %rcx /*  save RDX */
 186     mov $-1, %rax
 187     mov %rax, %rdx
 188     xrstor .Lxsave_clear(%rip)
 189     mov %rcx, %rdx /*  restore RDX */
 190 /*  clear flags */
 191     pushq $0
 192     popfq
 193 /*  restore user registers */
 194     mov %gs:tcsls_user_r12,%r12
 195     mov %gs:tcsls_user_r13,%r13
 196     mov %gs:tcsls_user_r14,%r14
 197     mov %gs:tcsls_user_r15,%r15
 198     mov %gs:tcsls_user_retip,%rbx
 199     mov %gs:tcsls_user_rsp,%rsp
 200     mov %gs:tcsls_user_rbp,%rbp
 201     fldcw %gs:tcsls_user_fcw
 202     ldmxcsr %gs:tcsls_user_mxcsr
 203 /*  exit enclave */
 204     mov $0x4,%eax /*  EEXIT */
 205     enclu
 206 /*  end sgx_entry */
 207
 208 .Lreentry_panic:
 209     orq $8,%rsp
 210     jmp abort_reentry
 211
 212 /*  This *MUST* be called with 6 parameters, otherwise register information */
 213 /*  might leak! */
 214 .global usercall
 215 usercall:
 216     test %rcx,%rcx            /* check `abort` function argument */
 217     jnz .Lusercall_abort      /* abort is set, jump to abort code (unlikely forward conditional) */
 218     jmp .Lusercall_save_state /* non-aborting usercall */
 219 .Lusercall_abort:
 220 /* set aborted bit */
 221     movb $1,.Laborted(%rip)
 222 /* save registers in DEBUG mode, so that debugger can reconstruct the stack */
 223     testb $0xff,DEBUG(%rip)
 224     jz .Lusercall_noreturn
 225 .Lusercall_save_state:
 226 /*  save callee-saved state */
 227     push %r15
 228     push %r14
 229     push %r13
 230     push %r12
 231     push %rbp
 232     push %rbx
 233     sub $8, %rsp
 234     fstcw 4(%rsp)
 235     stmxcsr (%rsp)
 236     movq %rsp,%gs:tcsls_last_rsp
 237 .Lusercall_noreturn:
 238 /*  clear general purpose register state */
 239     /*  RAX overwritten by ENCLU */
 240     /*  RBX set by sgx_exit */
 241     /*  RCX overwritten by ENCLU */
 242     /*  RDX contains parameter */
 243     /*  RSP set by sgx_exit */
 244     /*  RBP set by sgx_exit */
 245     /*  RDI contains parameter */
 246     /*  RSI contains parameter */
 247     /*  R8 contains parameter */
 248     /*  R9 contains parameter */
 249     xor %r10,%r10
 250     xor %r11,%r11
 251     /*  R12 ~ R15 set by sgx_exit */
 252 /*  extended registers/flags cleared by sgx_exit */
 253 /*  exit */
 254     jmp .Lsgx_exit
 255 .Lusercall_ret:
 256     movq $0,%gs:tcsls_last_rsp
 257 /*  restore callee-saved state, cf. "save" above */
 258     mov %r11,%rsp
 259     ldmxcsr (%rsp)
 260     fldcw 4(%rsp)
 261     add $8, %rsp
 262     pop %rbx
 263     pop %rbp
 264     pop %r12
 265     pop %r13
 266     pop %r14
 267     pop %r15
 268 /*  return */
 269     mov %rsi,%rax /*  RAX = return value */
 270     /* NOP: mov %rdx,%rdx */ /*  RDX = return value */
 271     ret
 272
 273 /*
 274 The following functions need to be defined externally:
 275 ```
 276 // Called by entry code on re-entry after exit
 277 extern "C" fn abort_reentry() -> !;
 278
 279 // Called once when a TCS is first entered
 280 extern "C" fn tcs_init(secondary: bool);
 281
 282 // Standard TCS entrypoint
 283 extern "C" fn entry(p1: u64, p2: u64, p3: u64, secondary: bool, p4: u64, p5: u64) -> (u64, u64);
 284 ```
 285 */
 286
 287 .global get_tcs_addr
 288 get_tcs_addr:
 289     mov %gs:tcsls_tcs_addr,%rax
 290     ret
 291
 292 .global get_tls_ptr
 293 get_tls_ptr:
 294     mov %gs:tcsls_tls_ptr,%rax
 295     ret
 296
 297 .global set_tls_ptr
 298 set_tls_ptr:
 299     mov %rdi,%gs:tcsls_tls_ptr
 300     ret
 301
 302 .global take_debug_panic_buf_ptr
 303 take_debug_panic_buf_ptr:
 304     xor %rax,%rax
 305     xchg %gs:tcsls_debug_panic_buf_ptr,%rax
 306     ret