src/etc/vim/syntax/rust.vim

   1 " Vim syntax file
   2 " Language:     Rust
   3 " Maintainer:   Patrick Walton <pcwalton@mozilla.com>
   4 " Maintainer:   Ben Blum <bblum@cs.cmu.edu>
   5 " Maintainer:   Chris Morgan <me@chrismorgan.info>
   6 " Last Change:  2014 Feb 27
   7
   8 if version < 600
   9   syntax clear
  10 elseif exists("b:current_syntax")
  11   finish
  12 endif
  13
  14 " Syntax definitions {{{1
  15 " Basic keywords {{{2
  16 syn keyword   rustConditional match if else
  17 syn keyword   rustOperator    as
  18
  19 syn match     rustAssert      "\<assert\(\w\)*!" contained
  20 syn match     rustFail        "\<fail\(\w\)*!" contained
  21 syn keyword   rustKeyword     break
  22 syn keyword   rustKeyword     box nextgroup=rustBoxPlacement skipwhite skipempty
  23 syn keyword   rustKeyword     continue
  24 syn keyword   rustKeyword     extern nextgroup=rustExternCrate,rustObsoleteExternMod skipwhite skipempty
  25 syn keyword   rustKeyword     fn nextgroup=rustFuncName skipwhite skipempty
  26 syn keyword   rustKeyword     for in if impl let
  27 syn keyword   rustKeyword     loop once proc pub
  28 syn keyword   rustKeyword     return super
  29 syn keyword   rustKeyword     unsafe virtual while
  30 syn keyword   rustKeyword     use nextgroup=rustModPath skipwhite skipempty
  31 " FIXME: Scoped impl's name is also fallen in this category
  32 syn keyword   rustKeyword     mod trait struct enum type nextgroup=rustIdentifier skipwhite skipempty
  33 syn keyword   rustStorage     mut ref static const
  34
  35 syn keyword   rustInvalidBareKeyword crate
  36
  37 syn keyword   rustExternCrate crate contained nextgroup=rustIdentifier skipwhite skipempty
  38 syn keyword   rustObsoleteExternMod mod contained nextgroup=rustIdentifier skipwhite skipempty
  39
  40 syn match     rustIdentifier  contains=rustIdentifierPrime "\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*" display contained
  41 syn match     rustFuncName    "\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*" display contained
  42
  43 syn region    rustBoxPlacement matchgroup=rustBoxPlacementParens start="(" end=")" contains=TOP contained
  44 syn keyword   rustBoxPlacementExpr GC containedin=rustBoxPlacement
  45 " Ideally we'd have syntax rules set up to match arbitrary expressions. Since
  46 " we don't, we'll just define temporary contained rules to handle balancing
  47 " delimiters.
  48 syn region    rustBoxPlacementBalance start="(" end=")" containedin=rustBoxPlacement transparent
  49 syn region    rustBoxPlacementBalance start="\[" end="\]" containedin=rustBoxPlacement transparent
  50 " {} are handled by rustFoldBraces
  51
  52 " Reserved (but not yet used) keywords {{{2
  53 syn keyword   rustReservedKeyword alignof be do offsetof priv pure sizeof typeof unsized yield
  54
  55 " Built-in types {{{2
  56 syn keyword   rustType        int uint float char bool u8 u16 u32 u64 f32
  57 syn keyword   rustType        f64 i8 i16 i32 i64 str Self
  58
  59 " Things from the prelude (src/libstd/prelude.rs) {{{2
  60 " This section is just straight transformation of the contents of the prelude,
  61 " to make it easy to update.
  62
  63 " Core operators {{{3
  64 syn keyword   rustTrait       Copy Send Sized Share
  65 syn keyword   rustTrait       Add Sub Mul Div Rem Neg Not
  66 syn keyword   rustTrait       BitAnd BitOr BitXor
  67 syn keyword   rustTrait       Drop Deref DerefMut
  68 syn keyword   rustTrait       Shl Shr Index
  69 syn keyword   rustEnum        Option
  70 syn keyword   rustEnumVariant Some None
  71 syn keyword   rustEnum        Result
  72 syn keyword   rustEnumVariant Ok Err
  73
  74 " Functions {{{3
  75 "syn keyword rustFunction from_str
  76 "syn keyword rustFunction range
  77 "syn keyword rustFunction drop
  78
  79 " Types and traits {{{3
  80 syn keyword rustTrait Ascii AsciiCast OwnedAsciiCast AsciiStr IntoBytes
  81 syn keyword rustTrait ToCStr
  82 syn keyword rustTrait Char
  83 syn keyword rustTrait Clone
  84 syn keyword rustTrait Eq Ord TotalEq TotalOrd Ordering Equiv
  85 syn keyword rustEnumVariant Less Equal Greater
  86 syn keyword rustTrait Container Mutable Map MutableMap Set MutableSet
  87 syn keyword rustTrait FromIterator Extendable
  88 syn keyword rustTrait Iterator DoubleEndedIterator RandomAccessIterator CloneableIterator
  89 syn keyword rustTrait OrdIterator MutableDoubleEndedIterator ExactSize
  90 syn keyword rustTrait Num NumCast CheckedAdd CheckedSub CheckedMul
  91 syn keyword rustTrait Signed Unsigned
  92 syn keyword rustTrait Primitive Int Float FloatMath ToPrimitive FromPrimitive
  93 "syn keyword rustTrait Expect
  94 syn keyword rustTrait Box
  95 syn keyword rustTrait GenericPath Path PosixPath WindowsPath
  96 syn keyword rustTrait RawPtr
  97 syn keyword rustTrait Buffer Writer Reader Seek
  98 syn keyword rustTrait Str StrVector StrSlice OwnedStr IntoMaybeOwned
  99 syn keyword rustTrait StrAllocating
 100 syn keyword rustTrait ToStr IntoStr
 101 syn keyword rustTrait Tuple1 Tuple2 Tuple3 Tuple4
 102 syn keyword rustTrait Tuple5 Tuple6 Tuple7 Tuple8
 103 syn keyword rustTrait Tuple9 Tuple10 Tuple11 Tuple12
 104 syn keyword rustTrait CloneableVector ImmutableCloneableVector MutableCloneableVector
 105 syn keyword rustTrait ImmutableVector MutableVector
 106 syn keyword rustTrait ImmutableEqVector ImmutableTotalOrdVector MutableTotalOrdVector
 107 syn keyword rustTrait Vector VectorVector OwnedVector MutableVectorAllocating
 108 syn keyword rustTrait String
 109 syn keyword rustTrait Vec
 110
 111 "syn keyword rustFunction sync_channel channel
 112 syn keyword rustTrait SyncSender Sender Receiver
 113 "syn keyword rustFunction spawn
 114
 115 "syn keyword rustConstant GC
 116
 117 syn keyword   rustSelf        self
 118 syn keyword   rustBoolean     true false
 119
 120 " Other syntax {{{2
 121
 122 " If foo::bar changes to foo.bar, change this ("::" to "\.").
 123 " If foo::bar changes to Foo::bar, change this (first "\w" to "\u").
 124 syn match     rustModPath     "\w\(\w\)*::[^<]"he=e-3,me=e-3
 125 syn match     rustModPath     "\w\(\w\)*" contained " only for 'use path;'
 126 syn match     rustModPathSep  "::"
 127
 128 syn match     rustFuncCall    "\w\(\w\)*("he=e-1,me=e-1
 129 syn match     rustFuncCall    "\w\(\w\)*::<"he=e-3,me=e-3 " foo::<T>();
 130
 131 " This is merely a convention; note also the use of [A-Z], restricting it to
 132 " latin identifiers rather than the full Unicode uppercase. I have not used
 133 " [:upper:] as it depends upon 'noignorecase'
 134 "syn match     rustCapsIdent    display "[A-Z]\w\(\w\)*"
 135
 136 syn match     rustOperator     display "\%(+\|-\|/\|*\|=\|\^\|&\||\|!\|>\|<\|%\)=\?"
 137 " This one isn't *quite* right, as we could have binary-& with a reference
 138 syn match     rustSigil        display /&\s\+[&~@*][^)= \t\r\n]/he=e-1,me=e-1
 139 syn match     rustSigil        display /[&~@*][^)= \t\r\n]/he=e-1,me=e-1
 140 " This isn't actually correct; a closure with no arguments can be `|| { }`.
 141 " Last, because the & in && isn't a sigil
 142 syn match     rustOperator     display "&&\|||"
 143
 144 syn match     rustMacro       '\w\(\w\)*!' contains=rustAssert,rustFail
 145 syn match     rustMacro       '#\w\(\w\)*' contains=rustAssert,rustFail
 146
 147 syn match     rustSpecialError display contained /\\./
 148 syn match     rustSpecial     display contained /\\\([nrt0\\'"]\|x\x\{2}\|u\x\{4}\|U\x\{8}\)/
 149 syn match     rustStringContinuation display contained /\\\n\s*/
 150 syn region    rustString      start=+"+ skip=+\\\\\|\\"+ end=+"+ contains=rustSpecial,rustSpecialError,rustStringContinuation,@Spell
 151 syn region    rustString      start='r\z(#*\)"' end='"\z1' contains=@Spell
 152
 153 syn region    rustAttribute   start="#!\?\[" end="\]" contains=rustString,rustDeriving
 154 syn region    rustDeriving    start="deriving(" end=")" contained contains=rustTrait
 155
 156 " Number literals
 157 syn match     rustDecNumber   display "\<[0-9][0-9_]*\%([iu]\%(8\|16\|32\|64\)\=\)\="
 158 syn match     rustHexNumber   display "\<0x[a-fA-F0-9_]\+\%([iu]\%(8\|16\|32\|64\)\=\)\="
 159 syn match     rustOctNumber   display "\<0o[0-7_]\+\%([iu]\%(8\|16\|32\|64\)\=\)\="
 160 syn match     rustBinNumber   display "\<0b[01_]\+\%([iu]\%(8\|16\|32\|64\)\=\)\="
 161
 162 " Special case for numbers of the form "1." which are float literals, unless followed by
 163 " an identifier, which makes them integer literals with a method call or field access.
 164 " (This must go first so the others take precedence.)
 165 syn match     rustFloat       display "\<[0-9][0-9_]*\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\@!"
 166 " To mark a number as a normal float, it must have at least one of the three things integral values don't have:
 167 " a decimal point and more numbers; an exponent; and a type suffix.
 168 syn match     rustFloat       display "\<[0-9][0-9_]*\%(\.[0-9][0-9_]*\)\%([eE][+-]\=[0-9_]\+\)\=\(f32\|f64\)\="
 169 syn match     rustFloat       display "\<[0-9][0-9_]*\%(\.[0-9][0-9_]*\)\=\%([eE][+-]\=[0-9_]\+\)\(f32\|f64\)\="
 170 syn match     rustFloat       display "\<[0-9][0-9_]*\%(\.[0-9][0-9_]*\)\=\%([eE][+-]\=[0-9_]\+\)\=\(f32\|f64\)"
 171
 172 " For the benefit of delimitMate
 173 syn region rustLifetimeCandidate display start=/&'\%(\([^'\\]\|\\\(['nrt0\\\"]\|x\x\{2}\|u\x\{4}\|U\x\{8}\)\)'\)\@!/ end=/[[:cntrl:][:space:][:punct:]]\@=\|$/ contains=rustSigil,rustLifetime
 174 syn region rustGenericRegion display start=/<\%('\|[^[cntrl:][:space:][:punct:]]\)\@=')\S\@=/ end=/>/ contains=rustGenericLifetimeCandidate
 175 syn region rustGenericLifetimeCandidate display start=/\%(<\|,\s*\)\@<='/ end=/[[:cntrl:][:space:][:punct:]]\@=\|$/ contains=rustSigil,rustLifetime
 176
 177 "rustLifetime must appear before rustCharacter, or chars will get the lifetime highlighting
 178 syn match     rustLifetime    display "\'\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*"
 179 syn match   rustCharacter   /'\([^'\\]\|\\\(.\|x\x\{2}\|u\x\{4}\|U\x\{8}\)\)'/ contains=rustSpecial,rustSpecialError
 180
 181 syn region rustCommentLine                                        start="//"                      end="$"   contains=rustTodo,@Spell
 182 syn region rustCommentLineDoc                                     start="//\%(//\@!\|!\)"         end="$"   contains=rustTodo,@Spell
 183 syn region rustCommentBlock    matchgroup=rustCommentBlock        start="/\*\%(!\|\*[*/]\@!\)\@!" end="\*/" contains=rustTodo,rustCommentBlockNest,@Spell
 184 syn region rustCommentBlockDoc matchgroup=rustCommentBlockDoc     start="/\*\%(!\|\*[*/]\@!\)"    end="\*/" contains=rustTodo,rustCommentBlockDocNest,@Spell
 185 syn region rustCommentBlockNest matchgroup=rustCommentBlock       start="/\*"                     end="\*/" contains=rustTodo,rustCommentBlockNest,@Spell contained transparent
 186 syn region rustCommentBlockDocNest matchgroup=rustCommentBlockDoc start="/\*"                     end="\*/" contains=rustTodo,rustCommentBlockDocNest,@Spell contained transparent
 187 " FIXME: this is a really ugly and not fully correct implementation. Most
 188 " importantly, a case like ``/* */*`` should have the final ``*`` not being in
 189 " a comment, but in practice at present it leaves comments open two levels
 190 " deep. But as long as you stay away from that particular case, I *believe*
 191 " the highlighting is correct. Due to the way Vim's syntax engine works
 192 " (greedy for start matches, unlike Rust's tokeniser which is searching for
 193 " the earliest-starting match, start or end), I believe this cannot be solved.
 194 " Oh you who would fix it, don't bother with things like duplicating the Block
 195 " rules and putting ``\*\@<!`` at the start of them; it makes it worse, as
 196 " then you must deal with cases like ``/*/**/*/``. And don't try making it
 197 " worse with ``\%(/\@<!\*\)\@<!``, either...
 198
 199 syn keyword rustTodo contained TODO FIXME XXX NB NOTE
 200
 201 " Folding rules {{{2
 202 " Trivial folding rules to begin with.
 203 " TODO: use the AST to make really good folding
 204 syn region rustFoldBraces start="{" end="}" transparent fold
 205 " If you wish to enable this, setlocal foldmethod=syntax
 206 " It's not enabled by default as it would drive some people mad.
 207
 208 " Default highlighting {{{1
 209 hi def link rustDecNumber       rustNumber
 210 hi def link rustHexNumber       rustNumber
 211 hi def link rustOctNumber       rustNumber
 212 hi def link rustBinNumber       rustNumber
 213 hi def link rustIdentifierPrime rustIdentifier
 214 hi def link rustTrait           rustType
 215
 216 hi def link rustSigil         StorageClass
 217 hi def link rustSpecial       Special
 218 hi def link rustSpecialError  Error
 219 hi def link rustStringContinuation Special
 220 hi def link rustString        String
 221 hi def link rustCharacter     Character
 222 hi def link rustNumber        Number
 223 hi def link rustBoolean       Boolean
 224 hi def link rustEnum          rustType
 225 hi def link rustEnumVariant   rustConstant
 226 hi def link rustConstant      Constant
 227 hi def link rustSelf          Constant
 228 hi def link rustFloat         Float
 229 hi def link rustOperator      Operator
 230 hi def link rustKeyword       Keyword
 231 hi def link rustReservedKeyword Error
 232 hi def link rustConditional   Conditional
 233 hi def link rustIdentifier    Identifier
 234 hi def link rustCapsIdent     rustIdentifier
 235 hi def link rustModPath       Include
 236 hi def link rustModPathSep    Delimiter
 237 hi def link rustFunction      Function
 238 hi def link rustFuncName      Function
 239 hi def link rustFuncCall      Function
 240 hi def link rustCommentLine   Comment
 241 hi def link rustCommentLineDoc SpecialComment
 242 hi def link rustCommentBlock  rustCommentLine
 243 hi def link rustCommentBlockDoc rustCommentLineDoc
 244 hi def link rustAssert        PreCondit
 245 hi def link rustFail          PreCondit
 246 hi def link rustMacro         Macro
 247 hi def link rustType          Type
 248 hi def link rustTodo          Todo
 249 hi def link rustAttribute     PreProc
 250 hi def link rustDeriving      PreProc
 251 hi def link rustStorage       StorageClass
 252 hi def link rustObsoleteStorage Error
 253 hi def link rustLifetime      Special
 254 hi def link rustInvalidBareKeyword Error
 255 hi def link rustExternCrate   rustKeyword
 256 hi def link rustObsoleteExternMod Error
 257 hi def link rustBoxPlacementParens Delimiter
 258 hi def link rustBoxPlacementExpr rustKeyword
 259
 260 " Other Suggestions:
 261 " hi rustAttribute ctermfg=cyan
 262 " hi rustDeriving ctermfg=cyan
 263 " hi rustAssert ctermfg=yellow
 264 " hi rustFail ctermfg=red
 265 " hi rustMacro ctermfg=magenta
 266
 267 syn sync minlines=200
 268 syn sync maxlines=500
 269
 270 let b:current_syntax = "rust"