compiler/rustc_target/src/spec/mipsel_sony_psp_linker_script.ld

   1 ENTRY(module_start)
   2 SECTIONS
   3 {
   4   /* PRX format requires text to begin at 0 */
   5   .text 0 : { *(.text .text.*) }
   6
   7   /* Sort stubs for convenient ordering */
   8   .sceStub.text : { *(.sceStub.text) *(SORT(.sceStub.text.*)) }
   9
  10   /* PSP import library stub sections. Bundles together `.lib.stub.entry.*`
  11    * sections for better `--gc-sections` support. */
  12   .lib.stub.top : { *(.lib.stub.top) }
  13   .lib.stub :     { *(.lib.stub) *(.lib.stub.entry.*) }
  14   .lib.stub.btm : { *(.lib.stub.btm) }
  15
  16   /* Keep these sections around, even though they may appear unused to the linker */
  17   .lib.ent.top :  { KEEP(*(.lib.ent.top)) }
  18   .lib.ent :      { KEEP(*(.lib.ent)) }
  19   .lib.ent.btm :  { KEEP(*(.lib.ent.btm)) }
  20
  21   .eh_frame_hdr : { *(.eh_frame_hdr) }
  22
  23   /* Add symbols for LLVM's libunwind */
  24   __eh_frame_hdr_start = SIZEOF(.eh_frame_hdr) > 0 ? ADDR(.eh_frame_hdr) : 0;
  25   __eh_frame_hdr_end = SIZEOF(.eh_frame_hdr) > 0 ? . : 0;
  26   .eh_frame :
  27   {
  28     __eh_frame_start = .;
  29     KEEP(*(.eh_frame))
  30     __eh_frame_end = .;
  31   }
  32
  33   /* These are explicitly listed to avoid being merged into .rodata */
  34   .rodata.sceResident : { *(.rodata.sceResident) *(.rodata.sceResident.*) }
  35   .rodata.sceModuleInfo : { *(.rodata.sceModuleInfo) }
  36   /* Sort NIDs for convenient ordering */
  37   .rodata.sceNid : { *(.rodata.sceNid) *(SORT(.rodata.sceNid.*)) }
  38
  39   .rodata : { *(.rodata .rodata.*) }
  40   .data : { *(.data .data.*) }
  41   .gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
  42   .bss : { *(.bss .bss.*) }
  43
  44   /DISCARD/ : { *(.rel.sceStub.text .MIPS.abiflags .reginfo) }
  45 }