cmake/Modules/FindGettextLib.cmake

   1 # Package finder for gettext libs and include files
   2
   3 SET(CUSTOM_GETTEXT_PATH "${PROJECT_SOURCE_DIR}/../../gettext"
   4         CACHE FILEPATH "path to custom gettext")
   5
   6 # by default
   7 SET(GETTEXT_FOUND FALSE)
   8
   9 FIND_PATH(GETTEXT_INCLUDE_DIR
  10         NAMES libintl.h
  11         PATHS "${CUSTOM_GETTEXT_PATH}/include"
  12         DOC "gettext include directory")
  13
  14 FIND_PROGRAM(GETTEXT_MSGFMT
  15         NAMES msgfmt
  16         PATHS "${CUSTOM_GETTEXT_PATH}/bin"
  17         DOC "path to msgfmt")
  18
  19 if(APPLE)
  20         FIND_LIBRARY(GETTEXT_LIBRARY
  21                 NAMES libintl.a
  22                 PATHS "${CUSTOM_GETTEXT_PATH}/lib"
  23                 DOC "gettext *intl*.lib")
  24
  25         FIND_LIBRARY(ICONV_LIBRARY
  26                 NAMES libiconv.dylib
  27                 PATHS "/usr/lib"
  28                 DOC "iconv lib")
  29 endif(APPLE)
  30
  31 # modern Linux, as well as Mac, seem to not need require special linking
  32 # they do not because gettext is part of glibc
  33 # TODO check the requirements on other BSDs and older Linux
  34 IF (WIN32)
  35         IF(MSVC)
  36                 SET(GETTEXT_LIB_NAMES
  37                         libintl.lib intl.lib libintl3.lib intl3.lib)
  38         ELSE()
  39                 SET(GETTEXT_LIB_NAMES
  40                         libintl.dll.a intl.dll.a libintl3.dll.a intl3.dll.a)
  41         ENDIF()
  42         FIND_LIBRARY(GETTEXT_LIBRARY
  43                 NAMES ${GETTEXT_LIB_NAMES}
  44                 PATHS "${CUSTOM_GETTEXT_PATH}/lib"
  45                 DOC "gettext *intl*.lib")
  46         FIND_FILE(GETTEXT_DLL
  47                 NAMES libintl.dll intl.dll libintl3.dll intl3.dll
  48                 PATHS "${CUSTOM_GETTEXT_PATH}/bin" "${CUSTOM_GETTEXT_PATH}/lib"
  49                 DOC "gettext *intl*.dll")
  50         FIND_FILE(GETTEXT_ICONV_DLL
  51                 NAMES libiconv2.dll
  52                 PATHS "${CUSTOM_GETTEXT_PATH}/bin" "${CUSTOM_GETTEXT_PATH}/lib"
  53                 DOC "gettext *iconv*.lib")
  54 ENDIF(WIN32)
  55
  56 IF(GETTEXT_INCLUDE_DIR AND GETTEXT_MSGFMT)
  57         IF (WIN32)
  58                 # in the Win32 case check also for the extra linking requirements
  59                 IF(GETTEXT_LIBRARY AND GETTEXT_DLL AND GETTEXT_ICONV_DLL)
  60                         SET(GETTEXT_FOUND TRUE)
  61                 ENDIF()
  62         ELSE(WIN32)
  63                 # *BSD variants require special linkage as they don't use glibc
  64                 IF(${CMAKE_SYSTEM_NAME} MATCHES "BSD")
  65                         SET(GETTEXT_LIBRARY "intl")
  66                 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "BSD")
  67                 SET(GETTEXT_FOUND TRUE)
  68         ENDIF(WIN32)
  69 ENDIF()
  70
  71 IF(GETTEXT_FOUND)
  72         SET(GETTEXT_PO_PATH ${CMAKE_SOURCE_DIR}/po)
  73         SET(GETTEXT_MO_BUILD_PATH ${CMAKE_BINARY_DIR}/locale/<locale>/LC_MESSAGES)
  74         SET(GETTEXT_MO_DEST_PATH ${LOCALEDIR}/<locale>/LC_MESSAGES)
  75         FILE(GLOB GETTEXT_AVAILABLE_LOCALES RELATIVE ${GETTEXT_PO_PATH} "${GETTEXT_PO_PATH}/*")
  76         LIST(REMOVE_ITEM GETTEXT_AVAILABLE_LOCALES minetest.pot)
  77         MACRO(SET_MO_PATHS _buildvar _destvar _locale)
  78                 STRING(REPLACE "<locale>" ${_locale} ${_buildvar} ${GETTEXT_MO_BUILD_PATH})
  79                 STRING(REPLACE "<locale>" ${_locale} ${_destvar} ${GETTEXT_MO_DEST_PATH})
  80         ENDMACRO(SET_MO_PATHS)
  81 ELSE()
  82         SET(GETTEXT_INCLUDE_DIR "")
  83         SET(GETTEXT_LIBRARY "")
  84 ENDIF()