android/app/build.gradle

   1 apply plugin: 'com.android.application'
   2
   3 android {
   4         compileSdkVersion 33
   5         buildToolsVersion '33.0.2'
   6         ndkVersion "$ndk_version"
   7         defaultConfig {
   8                 applicationId 'net.minetest.minetest'
   9                 minSdkVersion 21
  10                 targetSdkVersion 33
  11                 versionName "${versionMajor}.${versionMinor}.${versionPatch}"
  12                 versionCode project.versionCode
  13         }
  14
  15         // load properties
  16         Properties props = new Properties()
  17         def propfile = file('../local.properties')
  18         if (propfile.exists())
  19                 props.load(new FileInputStream(propfile))
  20
  21         if (props.getProperty('keystore') != null) {
  22                 signingConfigs {
  23                         release {
  24                                 storeFile file(props['keystore'])
  25                                 storePassword props['keystore.password']
  26                                 keyAlias props['key']
  27                                 keyPassword props['key.password']
  28                         }
  29                 }
  30
  31                 buildTypes {
  32                         release {
  33                                 minifyEnabled true
  34                                 signingConfig signingConfigs.release
  35                         }
  36                 }
  37         }
  38
  39         // for multiple APKs
  40         splits {
  41                 abi {
  42                         enable true
  43                         reset()
  44                         include 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64'
  45                 }
  46         }
  47
  48         compileOptions {
  49                 sourceCompatibility JavaVersion.VERSION_1_8
  50                 targetCompatibility JavaVersion.VERSION_1_8
  51         }
  52 }
  53
  54 task prepareAssets() {
  55         def assetsFolder = "build/assets"
  56         def projRoot = "../.."
  57         def gameToCopy = "minetest_game"
  58
  59         copy {
  60                 from "${projRoot}/minetest.conf.example", "${projRoot}/README.md" into assetsFolder
  61         }
  62         copy {
  63                 from "${projRoot}/doc/lgpl-2.1.txt" into "${assetsFolder}"
  64         }
  65         copy {
  66                 from "${projRoot}/builtin" into "${assetsFolder}/builtin"
  67         }
  68         copy {
  69                 from "${projRoot}/client/shaders" into "${assetsFolder}/client/shaders"
  70         }
  71         copy {
  72                 from "../native/deps/armeabi-v7a/Irrlicht/Shaders" into "${assetsFolder}/client/shaders/Irrlicht"
  73         }
  74         copy {
  75                 from "${projRoot}/fonts" include "*.ttf" into "${assetsFolder}/fonts"
  76         }
  77         copy {
  78                 from "${projRoot}/games/${gameToCopy}" into "${assetsFolder}/games/${gameToCopy}"
  79         }
  80         fileTree("${projRoot}/po").include("**/*.po").forEach { poFile ->
  81                 def moPath = "${assetsFolder}/locale/${poFile.parentFile.name}/LC_MESSAGES/"
  82                 file(moPath).mkdirs()
  83                 exec {
  84                         commandLine 'msgfmt', '-o', "${moPath}/minetest.mo", poFile
  85                 }
  86         }
  87         copy {
  88                 from "${projRoot}/textures" into "${assetsFolder}/textures"
  89         }
  90
  91         file("${assetsFolder}/.nomedia").text = ""
  92
  93         task zipAssets(type: Zip) {
  94                 archiveFileName = "Minetest.zip"
  95                 from "${assetsFolder}"
  96                 destinationDirectory = file("src/main/assets")
  97         }
  98 }
  99
 100 preBuild.dependsOn zipAssets
 101
 102 // Map for the version code that gives each ABI a value.
 103 import com.android.build.OutputFile
 104
 105 def abiCodes = ['armeabi-v7a': 0, 'arm64-v8a': 1]
 106 android.applicationVariants.all { variant ->
 107         variant.outputs.each {
 108                 output ->
 109                         def abiName = output.getFilter(OutputFile.ABI)
 110                         output.versionCodeOverride = abiCodes.get(abiName, 0) + variant.versionCode
 111         }
 112 }
 113
 114 dependencies {
 115         implementation project(':native')
 116         implementation 'androidx.appcompat:appcompat:1.6.1'
 117 }